기업 실적 데이터로
이상징후와 변화 포인트 찾기

0실습 파일과 모듈의 흐름

Settings(기준값) 시트와 보정 시트는 2장에서 추가합니다.

• 각 파일은 앞 단계까지 완성된 상태. 중간에 따라오지 못하면 해당 단계 파일을 열고 이어서 진행.
• 5~6장은 4-2 파일에 시트를 추가해서 진행.

실습의 시작점

• 전월 대비 9월의 영업이익 수치가 차이가 큼
• 수집된 데이터에 잘못된 사항이 있는지 확인 필요

이 모듈의 흐름

• 2장은 데이터 오류(데이터가 틀린 것)를 찾음. 고쳐야 할 대상.
• 3~4장은 이상징후(데이터는 맞는데 사업에서 이상한 일이 일어난 것)를 찾음. 원인을 물어볼 대상.
• 오류를 먼저 걸러내지 않으면, 3장에서 엉뚱한 곳에 깃발이 꽂힘.
• 1장에서 만든 세로형 표 하나로 2~6장을 모두 진행함. 원본 가로형 시트는 분석에 다시 쓰지 않음. (원천 값을 확인할 때만 봄)

1예실 데이터 표를 분석 가능한 형태로 변경

1-1현재 표 자체에서 이상치 검토

전월 데이터와 차이, 비율을 계산해 봅니다.

실습 파일 1.현재표 자체에서 이상치 검토 : 실적_원본 시트 X열(차이) =W2-V2, Y열(비율) =W2/V2-1

1-2가로형 데이터 형식

가로형은 반복되는 비교 항목을 여러 열로 펼쳐 놓은 구조. 실습 파일의 예산_원본, 실적_원본 시트가 가로형 구조입니다.

• 한 행에 한 계정의 여러 달 실적이 포함
• 월 정보는 셀의 값이 아니라 2026-07, 2026-08 같은 열 이름에 들어 있음
• 다음 달이 추가되면 보통 오른쪽에 열을 하나 더 만듦

1-3세로형 데이터 형식 소개

세로형은 반복되는 항목을 하나의 열에 값으로 넣고, 관측값을 행으로 쌓는 구조. 위 표를 변환하면 아래와 같습니다.

• 한 행은 한 계정의 한 달 실적을 의미
• 월은 공통 열이 되고, 각 월은 그 열의 값이 됨
• 다음 달이 추가되어도 열 구조는 같고 행만 늘어남
• 하나의 숫자만 한 행에 들어가고, 나머지 열은 해당 숫자의 의미를 명시하는 구조

1-4예실 분석에서 Raw data를 세로형으로 변환하는 이유

1. 모든 월에 같은 계산 규칙을 적용하기 위함 가로형 데이터는 7월 차이, 8월 차이, 9월 차이를 각각의 열 위치 참조로 계산. 중간에 다른 데이터가 끼어드는 등 표 구조가 바뀌면 참조가 맞는지 관리해야 함. 세로형 데이터는 월 데이터 기준으로 같은 수식을 사용.
2. 분석 질문이 바뀌어도 같은 표를 사용하기 위함

   분석 질문	필요한 열과 조건
   9월 비용 합계는?	월 = 9월, 계정유형 = 비용 계열
   3분기 예산 대비 실적은?	월 = 7~9월, 예산·실적 집계
   부서별 초과 집행 규모는?	담당부서별 불리금액 집계
   전년 동월보다 증가했는가?	같은 계정, 12개월 전 월과 대응
   실적이 빠진 계정은?	기대 계정·월 목록과 실적 비교

   월을 날짜 값으로 두면 기간 계산의 기준이 명확해짐.
3. 자료를 위치가 아닌 의미로 연결하기 위함 예산표의 10번째 행과 실적표의 10번째 행이 같은 계정이라고 보장할 수 없다. 열 순서도 다를 수 있다.
   ✕ 잘못된 가정

   같은 위치에 있으니 같은 값이다.

   ✓ 연결 기준

   계정코드와 월이 같으니 비교할 값이다.

4. 검증 규칙을 표 전체에 적용하기 위함 “계정·월 조합은 한 번만 등장해야 한다”, “실적은 숫자여야 한다”, “모든 계정이 마스터에 있어야 한다” 같은 조건을 일괄 검사할 수 있음.

1-5열 피벗 해제

2예산과 실적 병합 및 데이터 오류 확인

2-1예산과 실적 병합

예산과 실적을 하나의 데이터로 합칩니다. 예산 데이터가 기준이 되므로 예산 데이터를 기준으로 병합합니다.

2-2행 수 확인 — 중복

병합이 끝나면 가장 먼저 행 수를 확인합니다. (상태 표시줄 또는 Ctrl+End)

• 예산세로의 행 수는 420행 (20계정 × 21개월)
• 그런데 병합 결과는 421행으로 한 행이 늘었음

예실 표에 열을 하나 추가해서 찾아봅니다.

=COUNTIFS([계정코드], [@계정코드], [월], [@월])

• 1보다 큰 행이 중복.
• 소모품비 2026년 7월 데이터에 중복 존재.
• 원천을 확인해 보면, 실적_원본 시트 맨 아래에 소모품비 행이 하나 더 있음. 7월 칸에만 값(8,400,000원)이 있고 나머지는 비어 있음.

반영 방법 — 원본 시트는 고치지 않음

Power Query의 실적세로에 그룹화 단계를 추가합니다.

• [모두 새로 고침] → 예실 표가 420행으로 돌아오는지 확인.
• 중복을 지우는(행 제거) 방식은 금액을 잃음. 그룹화 합산이 기본이고, 이중 계상으로 확인된 경우에만 제거.

2-3빈칸 확인 — 결측

예실 표의 실적 열에서 필터 → (비어 있음)을 선택하면 한 행이 나옵니다.

• 통신비 2026년 9월 실적이 비어 있음.

행 수의 함정

2-4값은 있는데 틀린 값 — 튀는 값 점검

세 번째 오류는 행 수로도, 빈칸으로도 안 잡힙니다. 값은 있고, 숫자이고, 자리도 맞는데 틀린 경우.

세로형 표에서는 같은 규칙을 모든 행에 한 번에 걸 수 있습니다. “이 계정의 평소 금액보다 몇 배인가”를 열로 만들어 봅니다.

=AVERAGEIFS([실적], [계정코드], [@계정코드])

=IF(ISNUMBER([@실적]), [@실적]/[@계정평균], "")

=IF([@평균대비배수]="", "", IF([@평균대비배수]>=튀는값배수기준, "원천확인", ""))

• Settings 시트를 추가하고 기준값을 정리. 튀는값배수기준(값: 3)을 이름으로 정의해서 사용. 기준값을 수식 안에 직접 쓰지 않음. (이름 정의 방법은 3-5)
• AVERAGEIFS는 빈칸을 건너뛰므로 통신비 결측이 평균을 망가뜨리지 않음.

필터에서 튀는값 = 원천확인을 고르면 두 행이 나옵니다.

접대비 반영 방법 — 보정 시트

원본 시트와 쿼리는 고치지 않습니다. 보정 내용을 표로 정리하고, 예실 표에서 그 값을 찾아 쓰는 방식.

=[@계정코드]&"|"&TEXT([@월],"yyyy-mm")

=[@계정코드]&"|"&TEXT([@월],"yyyy-mm")

=IFERROR(INDEX(보정[보정 값], MATCH([@키], 보정[키], 0)), "")

=IF([@보정값]<>"", [@보정값], IF([@실적]="", "", [@실적]))

• 실적 열은 원천 그대로 남아 있음. 보정 전후를 언제든 비교 가능.
• 튀는값은 원천 실적 기준이라 접대비 6월에 계속 원천확인이 표시됨. 같은 행에 보정값이 있으면 “확인 후 보정 완료”라는 뜻.
• 다음 달에 보정할 것이 생기면 보정 시트에 한 줄 추가. 원천에서 수정된 파일을 받으면 그 줄을 삭제.

2-5데이터 점검 정리

세 오류는 서로 성격이 다릅니다.

1. 결론이 안 바뀌는 오류도 반드시 고침소모품비처럼 고쳐도 결론이 안 바뀌는 오류도 고침. 안 고치면 다음 달에 금액이 커질 때 그대로 틀림.
2. 틀린 좋은 뉴스가 틀린 나쁜 뉴스보다 위험나쁜 뉴스는 누군가 확인하지만, 좋은 뉴스는 아무도 확인하지 않음.

2-6실습 — 세로형 통합표 만들고 오류 세 개 찾기

3차이 계산과 이상 항목 플래깅

실습 파일 : 3-1.데이터 상태와 불리금액 계산

3-1유리·불리는 계정유형이 결정

실적 − 예산을 그대로 차이로 쓰면

• 비용 계정은 양수면 나쁨. (더 썼음)
• 수익 계정은 양수면 좋음. (더 벌었음)

• 계정유형은 2-1에서 병합한 계정마스터에서 옴. 그래서 계정마스터를 붙인 것.
• 절댓값(ABS)으로 판정하지 않음. 절댓값을 쓰면 예산을 크게 절감한 계정이 빨간 경보로 올라옴. 경보 목록에 좋은 뉴스가 섞이면 그 목록은 곧 무시됨.

3-2데이터 상태와 계산 열

계산 전에 문지기를 하나 세웁니다. 데이터 상태가 OK가 아니면 계산하지 않습니다.

=IF([@분석실적]="","MISSING", IF(NOT(ISNUMBER([@분석실적])),"INVALID", IF([@예산]=0,"NO_BUDGET","OK")))

=IF([@데이터상태]<>"OK", "", IF([@계정유형]="수익", [@예산]-[@분석실적], [@분석실적]-[@예산]))

=IF([@데이터상태]<>"OK", "", [@불리금액]/[@예산])

• 모든 계산은 2-4에서 만든 분석실적을 사용. 키도 2-4에서 만들어 둠.
• [@분석실적]="" : 분석실적은 수식 결과라 빈칸이 ""(빈 문자열). ISBLANK로 확인하면 FALSE가 나와서 INVALID로 잘못 표시됨.

3-3비율만 보면 목록이 뒤집힘

2026-09만 필터한 뒤 두 번 정렬해 봅니다.

• 차이율 목록에만 있는 것 : 도서인쇄비(120%, 360만 원), 출장비(26%, 390만 원). 원인을 조사하는 인건비가 더 듦.
• 금액 목록에만 있는 것 : 제품매출, 원재료비. 원재료비는 차이율 3.4%라 비율 목록에서는 10위권. 그런데 금액은 5,400만 원.

3-4금액 × 비율, 그리고 중대금액 예외

실습 파일 4-2.피벗만들기의 예실 표, 2026-09 불리금액이 양수인 12개 계정. 임차료(0원)는 제외.

플래그 수식

=IF([@데이터상태]<>"OK", "DATA_CHECK",
  IF([@불리금액]>=당월중대금액기준, "확인",
  IF(AND([@차이율]>=당월차이율기준, [@불리금액]>=당월금액기준), "확인",
  IF(AND(-[@차이율]>=당월차이율기준, -[@불리금액]>=당월금액기준), "유리",
  ""))))

위에서 아래로 읽으면

1. 데이터가 이상하면 DATA_CHECK
2. 중대금액을 넘으면 그것만으로 확인
3. 비율과 금액을 둘 다 넘으면 확인
4. 반대 방향으로 둘 다 넘으면 유리표시만 하고 경보는 보내지 않음
5. 그 밖은 공백

• 2장에서 통신비를 비워 둔 덕분에 DATA_CHECK로 표시됨. 0으로 채웠다면 “유리”로 보였을 것.
• 2장에서 원천 확인한 수선비는 실제 사건이므로 확인 대상에 그대로 들어감.

3-5기준값은 Settings에서 이름으로

기준값을 수식 안에 직접 쓰지 않습니다.

• Settings 시트에 기준값을 정리하고, “이름 관리자” 설정
• 설정된 이름 그대로 수식에서 사용 가능

• 기준을 바꿀 때는 날짜와 이유를 기록하여 근거를 남기는 것이 좋음.
• 소리 없이 바꾸면 지난달 보고와 이번 달 보고를 비교할 수 없음.

3-6보이게 만들기

조건부 서식

L열 = 플래그 열 위치에 맞게 바꿔서 입력

피벗과 슬라이서

• 값에는 실적이 아니라 분석실적을 넣어야 보정 내용이 반영됨.
• 담당부서 슬라이서를 누르면 “우리 부서에서 확인할 항목”만 추출됨.
• 세로형 데이터 구조라 연도·월번호·담당부서·플래그 어느 것이든 필드로 바로 쓸 수 있음.

4비교 축을 늘려 구조적·일시적 판별

실습 파일 : 4-1.비교축 확장으로 구조적, 일시적 판별 (4-1 ~ 4-6), 4-2.피벗만들기 (4-7)

4-1예산은 진실이 아니라 의견

예산은 작년 말에 사람이 정한 숫자. 예산이 틀렸을 수도 있습니다.

그래서 비교 축을 다섯 개로 늘립니다.

4-2전년 동월과 전월

2-4에서 만든 키 열을 사용합니다. “12개월 전 키”를 만들어서 찾습니다.

=IFERROR(INDEX([분석실적], MATCH([@계정코드]&"|"&TEXT(EDATE([@월],-12),"yyyy-mm"), [키], 0)), "")

=IFERROR(INDEX([분석실적], MATCH([@계정코드]&"|"&TEXT(EDATE([@월],-1),"yyyy-mm"), [키], 0)), "")

• EDATE([@월], -12) : 12개월 전 날짜 반환
• MATCH는 중복이 있으면 첫 번째만 가져옴. 2장에서 소모품비 중복을 합산해 없앴기 때문에 믿을 수 있는 값. 중복을 방치했다면 조용히 틀림.

=IF(OR([@전년동월실적]="", [@데이터상태]<>"OK"), "", IF([@계정유형]="수익", [@전년동월실적]-[@분석실적], [@분석실적]-[@전년동월실적]))

=IF([@전년대비금액]="", "", [@전년대비금액]/[@전년동월실적])

• 불리금액과 같은 규칙으로 부호를 통일. 전년보다 나빠졌으면 양수.
• 예산 대비와 전년 대비를 같은 방향으로 읽을 수 있음.

4-3누계 — “이번 달은 괜찮았습니다”를 막음

=SUMIFS([예산], [계정코드], [@계정코드], [연도], [@연도], [월번호], "<="&[@월번호])

=SUMIFS([분석실적], [계정코드], [@계정코드], [연도], [@연도], [월번호], "<="&[@월번호])

=COUNTIFS([계정코드], [@계정코드], [연도], [@연도], [월번호], "<="&[@월번호], [데이터상태], "<>OK")

=IF([@누계결측]>0, "", IF([@계정유형]="수익", [@누계예산]-[@누계실적], [@누계실적] - [@누계예산]))

=IF([@누계불리금액]="", "", [@누계불리금액]/[@누계예산])

=IF([@누계결측]>0, "DATA_CHECK",
  IF([@누계불리금액]>=누계중대금액기준, "확인",
  IF(AND([@누계차이율]>=누계차이율기준, [@누계불리금액]>=누계금액기준),
  "확인", "")))

• 누계결측 : SUMIFS는 빈칸을 그냥 건너뜀. 통신비는 8개월치만 더한 값이 9개월 누계처럼 보이게 됨. 그래서 결측이 하나라도 있으면 누계를 계산하지 않음.
• 누계 기준은 당월 기준보다 비율은 더 민감하게, 금액은 더 크게 잡음.

• 제조경비 9월은 차이율 2.9%, 금액 870만 원. 어떤 당월 기준으로도 안 걸림. 그런데 9개월 누계는 7,417만 원.

4-4예산 여유율 — 예산 자체를 검증

그래서 “예산을 작년 실적보다 얼마나 여유 있게 잡았나”를 따로 봅니다.

=IF([@전년동월실적]="", "", ([@예산]-[@전년동월실적])/[@전년동월실적])

4-5연속 개월 수와 악화 여부

=COUNTIFS([계정코드], [@계정코드], [연도], [@연도], [월번호], ">="&MAX(1, [@월번호]-연속개월기준+1), [월번호], "<="&[@월번호], [플래그], "확인")

=IF(OR([@전년대비율]="", [@전년대비금액]=""), FALSE, AND([@전년대비율]>=전년대비악화기준, [@전년대비금액]>=당월금액기준))

• 연속개월 : 최근 3개월 중 몇 번 확인이 떴는지. 3이면 3개월 연속.
• 악화 : 전년 대비 비율과 금액을 둘 다 봄. 3장과 같은 논리. 비율만 보면 출장비(+51%, 641만 원) 같은 작은 계정이 걸림.
• 전년 데이터가 없는 2025년 행은 FALSE로 둠. 빈칸끼리 비교하면 오류가 남.

4-6판별표

다섯 축을 합쳐서 판별표 열에 판정합니다. 위에서부터 순서대로 확인하고, 처음 맞는 조건에서 멈춥니다.

=IF([@데이터상태]<>"OK", "데이터 확인",
  IF([@전년동월실적]="", "비교 불가",
  IF(AND([@플래그]<>"확인", [@악화], [@예산여유율]>=예산여유율기준), "예산이 느슨",
  IF(AND([@플래그]<>"확인", [@누계플래그]="확인"), "이미 벌어진 격차",
  IF([@플래그]<>"확인", "정상",
  IF([@전년대비율]<=-전년대비악화기준, "예산이 빡빡",
  IF(AND([@연속개월]>=연속개월기준, [@악화]), "구조적",
  IF(ABS([@전년대비율])<전년대비악화기준, "계절성", "일시적"))))))))

• 2번 줄 비교 불가를 반드시 넣음. 2025년 행에는 전년이 없어서, 이 줄이 없으면 ABS("")에서 #VALUE!가 쏟아짐.
• 순서가 논리. 예산이 빡빡(6번)을 구조적(7번)보다 위에 둬야 함. 광고선전비는 3개월 연속이면서 전년 대비 개선인데, 순서를 바꾸면 구조적으로 오판됨.
• Excel 2019 이상이면 IFS로 줄여 써도 됨. 판단 순서는 같음.

• 3장의 확인 7건이 구조적 4 / 일시적 1 / 계절성 1 / 예산이 빡빡 1로 나뉨.
• 3장에서 깃발이 안 꽂혔던 외주가공비, 제조경비가 새로 드러남.
• 수선비는 일시적이지만 누계 초과가 8,909만 원. “일시적이니 넘어가도 되나, 연간 예산을 넘길 것인가”는 따로 봐야 함.

4-7그림으로 확인 — 세로형을 피벗으로 펼쳐 보기

세로형은 저장하고 계산하는 형태. 여러 달을 한눈에 보는 가로 모양은 피벗이 언제든 만들어 줌. 원본 가로형 시트로 돌아갈 필요가 없습니다.

스파크라인 — 계정별 21개월 모양 4-2 파일 스파크라인 시트

• 값에 실적을 넣으면 접대비 6월이 보정 전 값(72,586,000)으로 튀어 보임. 보정이 반영된 분석실적을 사용.
• 세로형 데이터에서 만든 피벗이 가로 모양을 만들어 주므로, 그 위에 스파크라인을 그리면 됨.
• 스파크라인용 피벗은 필드를 바꾸지 않고 고정해서 씀. 필드를 바꾸면 칸 위치가 달라져 그림이 어긋남.

히트맵 — 20계정 × 21개월을 한 화면에 4-2 파일 히트맵 시트

(선택) 분기 비교 — 전분기 대비 실습 파일에는 없음 · 시간이 남을 때

• 수선비는 이 목록에 없음. 9월 한 달만 튀었으니 분기로 묶으면 희석됨.

5탐지 결과를 원인 목록으로

5-1이 데이터로는 원인을 계산할 수 없음

원재료비가 5,400만 원 초과.

• 단가가 올랐을 수도, 많이 썼을 수도, 비싼 원료 비중이 늘었을 수도 있음.
• 이걸 가르려면 수량과 단가가 따로 있어야 함. 실습 데이터에는 금액만 있음.

5-2원인 목록의 다섯 칸

• 가설은 서로 구분 가능해야 함. “비용이 늘었다”와 “지출이 증가했다”는 같은 말.
• 좋은 가설 두 개는 확인할 데이터가 서로 다름. “단가 상승”과 “물량 증가”는 확인 데이터가 다르므로 진짜 두 개.

5-3목록 좁히기 — 두 구역으로 나눔

실제 회사에서는 확인 대상이 40~50건 나옵니다. 전부 조사하면 아무것도 조사하지 못합니다. 불리금액 순으로 좁히면 되지만, 금액 순 하나로만 만들면 놓치는 것이 생깁니다.

• 외주가공비 : 당월 불리금액 −2,251만 원(유리). 금액 순위에 올라올 수 없음. 그런데 원가가 15% 오르는 중.
• 제조경비 : 당월 870만 원. 순위 아래쪽. 그런데 누계 7,417만 원.

원인목록 시트 만들기 4-2 파일에 이어서 진행

• 값으로 붙여넣음. 원인목록은 이번 달 보고용 사본. 예실 표가 바뀌어도 이번 달 목록은 그대로 남아야 함.
• 광고선전비는 원인목록에 넣지 않고 따로 “예산 편성 검토” 메모로 남김.

5-4AI에게 무엇을 주고 무엇을 받는가

표준 프롬프트

[역할] 월 예실 점검 결과를 검토하는 분석 보조자. 읽는 사람은 재무 비전공자다.

[데이터] 2026년 9월 예실 점검에서 확인 대상으로 분류된 계정이다.
단위는 원. 계정유형은 수익/매출원가/판관비.
"불리금액"은 양수면 불리(수익은 미달, 비용은 초과)를 뜻한다.
"판별표"는 우리가 이미 정한 분류다. 바꾸지 말고 그대로 받아들여라.

(여기에 원인목록 9행 붙여넣기 — 머리글 포함)

[요청]
① 계정별로 원인 가설 2~3개. 서로 확인 데이터가 다른 가설로 만들 것.
② 각 가설을 확인하거나 무너뜨릴 데이터를 1~2개.
③ 담당 부서에 물을 질문 한 줄. 예/아니오로 끝나지 않는 질문으로.

[금지]
- 표에 없는 수치를 추가하지 말 것
- 원인을 단정하지 말 것. 모든 원인은 "가설:"로 시작할 것
- 앞으로의 전망·예측을 쓰지 말 것
- "심각한", "위험한" 같은 형용사를 쓰지 말 것
- 판별표 결과를 바꾸거나 새로 제안하지 말 것

[형식] 계정별로 세 줄: 가설 / 필요 데이터 / 질문

• [금지]가 없으면 AI는 거의 반드시 원인을 단정하고 전망을 씀.
  예) “원자재 가격 상승으로 인한 것으로 판단되며 4분기에도 지속될 것으로 예상됩니다” → 표에 원자재 가격도, 4분기 데이터도 없음.
• 판별표를 바꾸지 말라고 하는 이유 : 판별표는 우리가 정한 규칙의 결과. AI가 다시 분류하면 기준이 매달 달라짐.

AI 답변 검수 네 가지

AI가 자주 만드는 나쁜 답

AI 답변 반영

1. 가설 두 개 고르기검수를 통과한 가설 중 2개를 골라 가설1, 가설2 칸에 입력.
2. 필요 데이터 확정필요데이터는 AI 초안을 보고 사람이 확정.
3. 기한·구분은 사람이기한, 구분(예: 율 인상 / 물량 증가 구분)은 사람이 정함.

6보고 문장 만들기

6-1세 줄이면 충분

• 경영진이 한 항목에 쓰는 시간은 30초 정도. 세 줄이 한계.
• 첫 줄이 없으면 못 믿고, 둘째 줄이 없으면 급한지 모르고, 셋째 줄이 없으면 아무 일도 일어나지 않음.
• 셋째 줄이 빠진 보고가 가장 많음. “확인이 필요합니다”로 끝나면 아무도 확인하지 않음.

• “예산 안쪽인데 보고합니다”를 써야 하는 문장.
• 첫 줄에서 “확인 대상이 아니다”를 먼저 인정하고, 둘째 줄을 “그러나”로 시작해서 뒤집음.

6-2넣지 않을 것

6-3수식이 문장을 씀

원인목록 표에 열 두 개를 추가합니다.

=IF([@계정유형]="수익", IF([@불리금액]>0, "미달", "초과 달성"), IF([@불리금액]>0, "초과", "절감"))

="[관찰] "&TEXT([@월],"m")&"월 "&[@계정명]&" 실적 "&TEXT([@분석실적],"#,##0")&"원, 예산 "&TEXT([@예산],"#,##0")&"원 대비 "&TEXT(ABS([@불리금액]),"#,##0")&"원 "&[@방향어]&"("&TEXT(ABS([@차이율]),"0.0%")&")."
  &CHAR(10)&"       1~"&TEXT([@월],"m")&"월 누계 "&TEXT(ABS([@누계불리금액]),"#,##0")&"원 "&IF([@누계불리금액]>0,"불리","유리")&"("&TEXT(ABS([@누계차이율]),"0.0%")&")."
  &CHAR(10)&"[패턴] 최근 3개월 중 "&[@연속개월]&"개월 확인 대상. 전년 동월 대비 "&TEXT(ABS([@전년대비율]),"0.0%")&IF([@전년대비율]>0," 악화"," 개선")&". "&[@판별표]&"으로 판단."
  &CHAR(10)&"[확인] "&[@담당부서]&"에 요청: "&[@필요데이터]&". "&TEXT([@기한],"m/d")&"까지. ("&[@구분]&")"

1. 한 줄로 입력수식이 길어서 줄을 나눠 적었음. 엑셀에는 한 줄로 이어서 입력. (복사 버튼은 한 줄로 붙여 줌. 수식 입력줄에서 Alt+Enter로 줄을 나눠도 됨)
2. 텍스트 줄 바꿈 켜기셀 서식에서 [맞춤] → [텍스트 줄 바꿈]을 켜야 CHAR(10) 줄바꿈이 보임.
3. 숫자는 절댓값, 방향은 한국어 단어ABS로 숫자를 쓰고 방향은 미달/초과/절감으로 씀. -338,448,000원보다 338,448,000원 미달이 읽기 쉬움.
4. 부서를 먼저, 요청 내용을 뒤에조사(을/를)가 붙는 자리에 변수를 두지 않는 것이 한국어 문장 조립의 요령.
5. 재료의 일부는 사람이 채움[@필요데이터], [@기한], [@구분]은 5장에서 사람이 채운 칸. 수식이 문장을 쓰지만, 재료의 일부는 사람이 채움.
6. [A] 구역용 수식[B] 구역은 “예산 대비 정상인데 보고하는 이유”를 먼저 써야 해서 뼈대가 다름. [B] 구역은 손으로 씀.

6-4AI로 다듬기 — 숫자는 건드리지 못하게

[역할] 사내 보고 문장을 다듬는 편집자.
[원문] (아래 3줄)
[요청] ① 문장을 짧게 ② 중복 표현 제거 ③ 경영진이 30초에 읽을 수 있게
[금지] 숫자·단위 변경, 새로운 원인 추가, 예측 표현, 과장 형용사, 부서 비난
[유지] 모든 숫자와 단위 / [관찰]·[패턴]·[확인] 구조 / 담당과 기한
[출력] 다듬은 3줄만. 설명 없이.

6-5보고문 확인

1. 지급수수료 세 줄을 손으로 먼저 써 봄
2. 보고문 열에서 만든 지급수수료 문장과 숫자가 같은지 비교
3. [B] 구역 외주가공비는 손으로 씀“확인 대상이 아니다” → “그러나” 순서
4. 한 건을 소리 내어 읽어 봄

7정리

7-11-1 표에서 판단하기 어려웠던 것들은 어떻게 풀렸나

7-2핵심 원칙

1. 원천은 고치지 않는다세로형 계산용 표를 따로 만든다.
2. 세로형으로 저장·계산하고, 가로 모양은 피벗으로 펼쳐 본다
3. 행 수가 같다고 데이터가 같은 것은 아니다
4. 오류를 먼저 걸러낸다근거가 있으면 보정 시트에 기록해 분석실적에 반영, 근거가 없으면 비워 두고 표시.
5. 유리·불리는 계정유형이 결정한다절댓값으로 판정하지 않는다.
6. 비율과 금액을 함께 본다기준값은 Settings에 두고 이력을 남긴다.
7. 예산은 의견이다전년 동월과 예산 여유율로 예산 자체를 검증한다.
8. 계산은 엑셀이, 가설은 AI가, 판단과 책임은 사람이